athenix/glue/boot.nix

# ============================================================================
# Boot & Storage Configuration
# ============================================================================
# This module defines:
# - Disko partition layout (EFI, swap, root)
# - Bootloader configuration (systemd-boot with Plymouth)
# - Filesystem options (device, swap size)
# - Build method options (used by installer/artifacts.nix)
# - Convenience options (forUser, useHostPrefix)

{ config, lib, ... }:

{
  options.athenix = {
    host = {
      useHostPrefix = lib.mkOption {
        type = lib.types.bool;
        default = true;
        description = "Whether to prepend the host prefix to the hostname (used in inventory and hosts/default.nix).";
      };
      filesystem = {
        device = lib.mkOption {
          type = lib.types.str;
          description = "The main disk device to use for installation.";
        };
        useSwap = lib.mkOption {
          type = lib.types.bool;
          default = true;
          description = "Whether to create and use a swap partition.";
        };
        swapSize = lib.mkOption {
          type = lib.types.str;
          description = "The size of the swap partition.";
        };
      };
    };
  };

  config = {
    # ========== Disk Partitioning (Disko) ==========
    disko.enableConfig = lib.mkDefault true;

    disko.devices = {
      disk.main = {
        type = "disk";
        device = config.athenix.host.filesystem.device;
        content = {
          type = "gpt";
          partitions = {
            # EFI System Partition
            ESP = {
              name = "ESP";
              label = "BOOT";
              size = "1G";
              type = "EF00";
              content = {
                type = "filesystem";
                format = "vfat";
                mountpoint = "/boot";
                mountOptions = [ "umask=0077" ];
                extraArgs = [
                  "-n"
                  "BOOT"
                ];
              };
            };

            # Swap Partition (size configurable per host)
            swap = lib.mkIf config.athenix.host.filesystem.useSwap {
              name = "swap";
              label = "swap";
              size = config.athenix.host.filesystem.swapSize;
              content = {
                type = "swap";
              };
            };

            # Root Partition (takes remaining space)
            root = {
              name = "root";
              label = "root";
              size = "100%";
              content = {
                type = "filesystem";
                format = "ext4";
                mountpoint = "/";
                extraArgs = [
                  "-L"
                  "ROOT"
                ];
              };
            };
          };
        };
      };
    };

    # Bootloader Configuration
    boot = {
      loader.systemd-boot.enable = true;
      loader.efi.canTouchEfiVariables = true;
      plymouth.enable = true;

      # Enable "Silent boot"
      consoleLogLevel = 3;
      initrd.verbose = false;

      # Hide the OS choice for bootloaders.
      # It's still possible to open the bootloader list by pressing any key
      # It will just not appear on screen unless a key is pressed
      loader.timeout = lib.mkDefault 0;
    };

    # Set your time zone.
    time.timeZone = "America/New_York";

    # Select internationalisation properties.
    i18n.defaultLocale = "en_US.UTF-8";

    i18n.extraLocaleSettings = {
      LC_ADDRESS = "en_US.UTF-8";
      LC_IDENTIFICATION = "en_US.UTF-8";
      LC_MEASUREMENT = "en_US.UTF-8";
      LC_MONETARY = "en_US.UTF-8";
      LC_NAME = "en_US.UTF-8";
      LC_NUMERIC = "en_US.UTF-8";
      LC_PAPER = "en_US.UTF-8";
      LC_TELEPHONE = "en_US.UTF-8";
      LC_TIME = "en_US.UTF-8";
    };

    systemd.sleep.extraConfig = ''
      SuspendState=freeze
      HibernateDelaySec=2h
    '';
  };
}